Простая автоматика управления клапаном отбора (Страница 1 из 2)

 //********Управление клапаном по датчику 2/3************
  if (sensors.getTempCByIndex(1) > klapanTmp + 0.4) // если температура датчика 2/3, подросла на 0,4
  {
    pauseKlapan = millis() / 1000;
    if (pauseKlapan >= 5)   // если прошло больше 5 секунд
    {
      digitalWrite(KLAPAN, HIGH);  // закрываем клапан отбора
      digitalWrite(LED_KLAPAN, HIGH);  // зажигаем индикатор клапана отбора
    }
  }
  if (sensors.getTempCByIndex(1) <= klapanTmp)
  {
    digitalWrite(KLAPAN, LOW);  // открываем клапан отбора
    digitalWrite(LED_KLAPAN, LOW);  // гасим индикатор клапана отбора
  }

#include <OneWire.h>                      // Библиотеки для DS18b20
#include <DallasTemperature.h>            // ----------------------
#define ONE_WIRE_BUS 10                   // D10 пин для DS18b20
OneWire oneWire(ONE_WIRE_BUS);
DallasTemperature sensors(&oneWire);      //Создаём объект sensors для работы с ds18b20

#include <Adafruit_BMP085.h>              // Подключаем библиотеку для работы с датчиками BMP180 или BMP280
Adafruit_BMP085 bmp;                      // Создаём объект bmp для работы с датчиком адрес которого на шине I2C установлен по умолчанию.

#include <Wire.h>                         // библиотека для управления устройствами по I2C 
#include <LCD_1602_RUS.h>                 // подключаем русскую библиотеку для LCD, 
                                          // LiquidCrystal_I2C.h должна быть установлена в системе 
LCD_1602_RUS lcd(0x3F,16,2);              // присваиваем имя lcd для дисплея 16х2 на адресе 0x3F
    
                    //--ПИНЫ ЭНКОДЕРА--
#define CLK 5                             // D5
#define DT 6                              // D6
#define SW 7                              // D7
                    //--ПИНЫ ЭНКОДЕРА--

#define VLV 2       //--ПИН КЛАПАНА--     // D2
    
    #define  INTERVAL  1000UL             // 1 секунда, базовый интервал
    
    float actual;                                 // расчётная температура с учётом атмосферного давления
    float press;                                  // атмосферное давление
    float vape;                                   // температура пара
    float counter = 78.00;                        // переменная заданной (табличной, для Н.У.) темературы, °C
    boolean DT_now, DT_last, SW_now, VLV_now;     // состояния пинов энкодера и клапана


    void setup() {
      sensors.begin();

      pinMode (CLK, INPUT);
      pinMode (DT, INPUT);
      pinMode (SW, INPUT);
      pinMode (VLV, OUTPUT);
      DT_last = digitalRead(CLK);         // читаем начальное положение CLK

  if (!bmp.begin()) {                     // инициализация датчика BMP180
  Serial.println("Could not find a valid BMP085 sensor, check wiring!");
  while (1) {}
  }
   
      lcd.init();                             // инициализация LCD дисплея
      lcd.backlight();                        // включение подсветки дисплея
   
      lcd.setCursor(5,0);                     // ставим курсор на 5 символ первой строки
      lcd.print("°>");                        // печатаем
      lcd.setCursor(7,0);                     // ставим курсор на 5 символ первой строки
      lcd.print("O");                         // печатаем      
      lcd.setCursor(8,0);                     // ставим курсор на 8 символ первой строки
      lcd.print("<");                         // печатаем

      lcd.setCursor(10,0);                    // ставим курсор на 10 символ первой строки
      lcd.print(counter);                     // печатаем

      lcd.setCursor(15,0);                    // ставим курсор на 15 символ первой строки
      lcd.print("°");                         // печатаем
  
      lcd.setCursor(5,1);                     // ставим курсор на 5 символ второй строки
      lcd.print("°C");                        // печатаем
      
      lcd.setCursor(8,1);
      lcd.print(bmp.readPressure()*0.007500616827042);      
      
      lcd.setCursor(14,1);                    // ставим курсор на 14 символ второй строки
      lcd.print("мм");                        // печатаем

      press = bmp.readPressure();             // считываем атм. давление на старте


    }
      
    void loop() {
      SW_now = digitalRead(SW);               // проверяем, не нажата ли кнопка энкодера
      if (SW_now == HIGH) {                   // если нажата, то
        encoderTick();                        // считаем щелчки поворота
      } else {
        static unsigned long previousMillis = 0;        // храним время последнего измерения
        if(millis() - previousMillis > 30*INTERVAL) {   // проверяем, не истек ли интервал. если да, то
        previousMillis = millis();                      // сохраняем время последнего измерения и
        psensorMeasure();                               // слушаем датчик атмосферы
        } else {                              
          dallas();                           // все остальное время выполняем отработку температуры
        }
      }
    }
    
    void encoderTick() {
      DT_now = digitalRead(CLK);          // читаем текущее положение CLK
      if (DT_now != DT_last) {            // если предыдущее и текущее положение CLK разные, значит был поворот
        if (digitalRead(DT) != DT_now) {  // если состояние DT отличается от CLK, значит крутим по часовой стрелке
          counter += 0.05;                // прибавить счётчик
        } else {                          // если совпадают, значит против часовой
          counter -= 0.05;                // убавить счётчик
        }
        lcd.setCursor(10,0);              // ставим курсор на 10 символ первой строки
        lcd.print(counter);               // печатаем заданную температуру
      }
      DT_last = DT_now;                   // обновить значение
    }

    void psensorMeasure() {
      press = bmp.readPressure();
      lcd.setCursor(8,1);
      lcd.print(press*0.007500616827042);
    }
    
    void dallas() {
      VLV_now = digitalRead (VLV);
      actual = (press*0.007500616827042-760)*0.034+counter;
      static unsigned int cntdwn;                     // обратный отсчёт для задержки открытия
      static unsigned long previousMillis = 0;        // храним время последнего измерения
      if(millis() - previousMillis >= INTERVAL){      // проверяем, не истек ли интервал. если да, то
      previousMillis = millis();                      // сохраняем время последнего измерения и      
      sensors.requestTemperatures();                  // опрашиваем датчик температуры
      vape = sensors.getTempCByIndex(0);              // обновляем значение переменной температуры пара
      lcd.setCursor(0,1);
      lcd.print(vape);                                // печатаем расчётную температуру
      lcd.setCursor(0,0);
      lcd.print(actual);                              // печатаем текущую температуру пара
        if (vape > actual+0.4) {                      // если температура на датчике превысила расчётную на заданную дельту
        digitalWrite (VLV, HIGH);                     // закрываем клапан
        lcd.setCursor(7,0);                           // ставим курсор на 7 символ первой строки
        lcd.print("X");                               // печатаем         
        cntdwn = 7;                                   // взводим обратный отсчёт
        } else {
          if  (VLV_now == HIGH && vape <= actual && cntdwn > 0){  // если температура на датчике = расчётной или ниже, а клапан ещё закрыт и обратный отсчёт не закончен
          cntdwn -= 1;                                            // уменьшаем обратный отсчёт на 1      
          lcd.setCursor(7,0);                         // ставим курсор на 7 символ первой строки
          lcd.print(cntdwn);                          // печатаем          
          }
          if  (VLV_now == HIGH && vape <= actual && cntdwn == 0){ 
            digitalWrite (VLV, LOW);                  // открываем клапан
            lcd.setCursor(7,0);                       // ставим курсор на 5 символ первой строки
            lcd.print("O");                           // печатаем
          }
        }
      }
    }