Узел отбора на перистальтическом насосе (Страница 7 из 53)

// дисплей ТМ 1637
//  8 microsteps/step
const int stepPin = 2;
 int i=0;
 int ml=0;
#define CLK 9
#define DIO 10
#include "GyverTM1637.h"
GyverTM1637 disp(CLK, DIO);
#include <RotaryEncoder.h>
// Setup a RoraryEncoder for pins A2 and A3:
RotaryEncoder encoder(A2, A3);
void setup()
{
   disp.clear();
 disp.brightness(7);  // яркость минимум =0, стандарт=2,  максимум=7)
    Serial.begin(57600);
  pinMode(stepPin, OUTPUT);
    // You may have to modify the next 2 lines if using other pins than A2 and A3
  PCICR |= (1 << PCIE1);    // This enables Pin Change Interrupt 1 that covers the Analog input pins or Port C.
  PCMSK1 |= (1 << PCINT10) | (1 << PCINT11);  // This enables the interrupt for pin 2 and 3 of Port C.
}
// The Interrupt Service Routine for Pin Change Interrupt 1
// This routine will only be called on any signal change on A2 and A3: exactly where we need to check.
ISR(PCINT1_vect) {
  encoder.tick(); // just call tick() to check the state.
}

void loop()
{
  static int pos = 10;
  int newPos = encoder.getPosition();
  if (pos != newPos) {
       if (newPos <1) newPos=1;
    pos = newPos;
    
   ml=newPos*10;//шаг 10мл
   if (ml>2500)ml=2500;
   i=220000/ml;
 
   disp.displayInt(ml);
  }
    digitalWrite(stepPin, HIGH);
    delayMicroseconds(i);
    digitalWrite(stepPin, LOW);
    delayMicroseconds(i);
}

// энкодер с 3 внешнми подтягивающими резисторами 10К

#include "GyverEncoder.h" //  библиотека    https://alexgyver.ru/encoder/
#include <TimerOne.h>
#include <TM1637.h>


// Подключенме энкодера
#define CLK_EN 6
#define DT 7
#define SW 8
#define ENCODER_GND 5 // GND энкодера подключено к этому пину для удобства монтажа

// подключение драйвера шагового двигателя
#define M_0 12 // установка микрошага
#define M_1 13
#define M_2 14
#define STEP_PIN 15
#define DIR_PIN  16  // направление вращения

// подключение трехпозиционного тумблера
#define SW_0 4
#define SW_1 3
#define SW_GND 2 // GND тумблера подключено к этому пину для удобства монтажа

// подключение светодиода
#define LED 9

// подключение TM1637
#define CLK 10 //pin TM1637
#define DIO 11 //pin TM1637


Encoder enc1(CLK_EN, DT, SW); //экземпляр энодера

TM1637 tm1637(CLK,DIO); // экземпляр объекта типа TM1637

int const KOEFF_LED = 50; // отношение (нужно подобрать)скорости смены импульсов на двигателе и скорости мигания светодиода
int const REG_B = 2; // базовая скорость отбора "тела"
int const REG_H = 70; // базовая скорость отбора "голов"

byte inFlagSw = 0; // состояние тумблера
bool MICRO_STEP [3] = {0,0,0}; // задает микрошаг
bool DIRECTION = false; // направление вращения

// служебные переменные для прерывания по таймеру
volatile unsigned int motorTimerCount = 0;
volatile unsigned long int ledTimerCount = 0; 
volatile unsigned int encoderTimerCount = 0;
int const long  TIMER_PERIOD = 250; // период срабатывания таймера
volatile  bool ledState = false; // задает состояние светодиода
volatile  int motorPulsPause = 77; // пауза между импульсами шагового двигателя (тики таймера)
volatile bool flagMotorRun = true;  // запрет/разрешение работы двигателя
volatile bool motorPulse = false; //служебная переменная, чередование пдачи импудьса на мотор 0 1
int const MINIMUM_PAUSE = 1; //максимальная скорость вращение (количество тиков паузы)
int const MAXIMUM_PAUSE = 100; //минимальная скорость вращение (количество тиков паузы


unsigned int ledTimerPause = 0;  // определяет частоту мигания светодиода

int dispDigits = 9999; // переменная для вывода на дисплей

//==============================================================================================
void setup() {
Serial.begin(9600);
setPinsMode (); //  установка и инициализация пинов вынесена в отдельную процедуру
enc1.setType(TYPE2);    // тип энкодера TYPE1 одношаговый, TYPE2 двухшаговый. "Если ваш энкодер работает странно, смените тип"
tm1637.init();// инициализация TM1637
tm1637.set(5);//установка яркости дисплея 0-7
tm1637.clearDisplay(); 
Timer1.initialize(TIMER_PERIOD); // инициализация таймера 1, период  
Timer1.attachInterrupt(timerInterrupt, TIMER_PERIOD); // задаем обработчик прерываний

}
//==============================================================================================
void loop() {
//если тумблер в положенн "вверх" устанавливаем скорость вращения regB     
if ( ! digitalRead(SW_0)){
  motorPulsPause = REG_B;
  if ( !(inFlagSw == 1)) {
    dispDigits = motorPulsPause;
    displayShow(); // выводим значение на дисплей
  }
  inFlagSw = 1;
 }
//если тумблер в положенн "вниз" устанавливаем скорость вращения regH
if ( ! digitalRead(SW_1)){
motorPulsPause = REG_H;
 if ( !(inFlagSw == 2)) {
    dispDigits = motorPulsPause;
     displayShow(); // выводим значение на дисплей
  }
  inFlagSw = 2;
 }
//если тумблер в положенн "среднее"  читаем энкодер
if ( digitalRead(SW_0) &  digitalRead(SW_1) ){
  inFlagSw = 3;
  readEncoder();
}
}
//==============================================================================================
void readEncoder(){
  if (enc1.isRight()) motorPulsPause++;      // если был поворот направо, увеличиваем на 1
  if (enc1.isLeft()) motorPulsPause--;      // если был поворот налево, уменьшаем на 1
  if (enc1.isFastR()) motorPulsPause = motorPulsPause + 10; // если был быстрый поворот направо, увеличиваем на 10
  if (enc1.isFastL()) motorPulsPause = motorPulsPause - 10; // если был быстрый поворот налево, уменьшаем на 10
 
  
  if (enc1.isRightH()) {
    digitalWrite (LED , true);  // если было удержание + поворот направо,
    flagMotorRun = true; // разрешаем вращение
  }
  if (enc1.isLeftH()) {
    digitalWrite (LED , false); // если было удержание + поворот налево, 
    flagMotorRun = false; // запрещаем вращение
  }

   if (enc1.isTurn()) {       // если был совершён поворот (индикатор поворота в любую сторону)
 // проверяем границы диапазона
      if ( motorPulsPause <= MINIMUM_PAUSE){
          motorPulsPause  = MINIMUM_PAUSE; 
      }
      if ( motorPulsPause > MAXIMUM_PAUSE){
         motorPulsPause  = MAXIMUM_PAUSE; 
      }

   
   dispDigits = motorPulsPause; 
   displayShow();// выводим значение при повороте
 //   Serial.println(motorPulsPause);  // выводим значение при повороте
  }  
}
void displayShow(){
 tm1637.clearDisplay(); 
//!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
// Внимание ! Здесь можно пересчитать паузу в милилитры в час при калибровке
 tm1637.display(dispDigits);  
 
 }


void timerInterrupt() {
 enc1.tick();
 motorTimerCount++;
 if ( motorTimerCount >= motorPulsPause) {
 // после того как количество тиков таймера сравняется с motorPulsPause   
// изменяется на противоположный уровень на STEP_PIN и сбрасывается счетчик
    motorTimerCount = 0;
    if ( flagMotorRun) { 
        motorPulse = !motorPulse;
          
        digitalWrite (STEP_PIN , motorPulse);
 // управление миганием светодиода (забавы ради)        
 // пусть мигает примерно с частотой падания капель        
       ledTimerCount++;
       if ( ledTimerCount >= motorPulsPause * KOEFF_LED) {
        ledTimerCount = 0;
        ledState = !ledState;
        digitalWrite (LED , ledState);
         }
       }
   }
}

void setPinsMode () {

 pinMode(LED, OUTPUT);
 digitalWrite (LED , true);
 
 pinMode(M_0, OUTPUT);
 pinMode(M_1, OUTPUT);
 pinMode(M_2, OUTPUT); 
 pinMode(STEP_PIN, OUTPUT); 
 pinMode(DIR_PIN, OUTPUT);  
 pinMode(ENCODER_GND, OUTPUT);  
 pinMode(SW_GND, OUTPUT);

 pinMode(SW_0, INPUT);
 pinMode(SW_1, INPUT);

 digitalWrite (M_0 , MICRO_STEP [0]);
 digitalWrite (M_1 , MICRO_STEP [1]); 
 digitalWrite (M_2 , MICRO_STEP [2]);
 digitalWrite (DIR_PIN , DIRECTION);
 digitalWrite (ENCODER_GND , false);
 digitalWrite (SW_GND , false);
  
}